Set: Main=[@Maincolor1]
Set: Secondary=[@ColorDet]
Set: Details=[@Maincolor3]
Set: Weapons=[@WeapType]

Header: SciFi Soldier Generator (D6 Rules) by Richard Kurbis

Table: SciRPG Soldier Maker v1-001
1:<b>UNIFORM:</b>\n {$main} [@Material1] [@Armor1]\n[@Details]\n<b>WEAPONS and EQUIPMENT:</b>\n[@Weapon1] [@Weapon4]\n[@Equipment1]
2:<b>UNIFORM:</b>\n {$main} [@Material1] [@Armor2]\n[@Details]\n<b>WEAPONS and EQUIPMENT:</b>\n[@Weapon2] [@Weapon4]\n[@Equipment1]
3:<b>UNIFORM:</b>\n {$main} [@Material1] [@Armor3]\n[@Details]\n<b>WEAPONS and EQUIPMENT:</b>\n[@Weapon3] [@Weapon4]\n[@Equipment1]


Table: Maincolor1
[@Colortype] Red
[@Colortype] Orange
[@Colortype] Yellow
[@Colortype] Green
[@Colortype] Blue
[@Colortype] Purple
White
Black
[|Dark|Light|] Gray
[@Colortype] Brown
[@Colortype] Tan
[@Maincolor3] Camouflage
[@Maincolor3] Camouflage
[@Maincolor3] Camouflage

Table: Maincolor2
[@Colortype] Red
[@Colortype] Orange
[@Colortype] Yellow
[@Colortype] Green
[@Colortype] Blue
[@Colortype] Purple
White
Black
[|Dark|Light|] Gray
[@Colortype] Brown
[@Colortype] Tan

Table: Maincolor3
White
Black
[|Dark|Light|] Gray
[@Colortype] Brown
[@Colortype] Tan

Table: ColorDet
[@Maincolor2]
[@Maincolor3]
[@Maincolor3]

Table: Colortype
\z
Light
Dark

Table: Material1
[@MaterialType]Leather
[@MaterialType]Cloth
Dura-plast
Plasti-Steel
[@MaterialType]Alloy

Table: MaterialType
Plasti-
Natural-
Synthetic-
Derma-
Hardened-
Bonded-
Plated-
Dura-

Table: Armor1
Dress Uniform (DR[|0|1|2])\n[@Acsents]

Table: Armor2
Combat Fatigues (DR[|2|3|4|5])\n[@Acsents1]
Combat Suit (DR[|4|5|6|7])\n[@Acsents1]
Riot Gear (DR[|3|4|5|6])\n[@Acsents2]
Battle Gear (DR[|5|6|7|8])\n[@Acsents2]

Table: Armor3
Light Power Armor (DR[|7|8|9|10])\n[@Acsents3]
Standard Power Armor (DR[|9|10|11|12])\n[@Acsents3]
Heavy Power Armor (DR[|12|13|14|15])\n[@Acsents3]

Table: Acsents
{$secondary} [@Acces1] [@Options1]
Table: Acsents1
{$secondary} [|Boots and Gloves|Boots] [@Options1]
Table: Acsents2
{$secondary} [@Acces1] [@Options2]
Table: Acsents3
{$secondary} [|Boots and Gloves|Boots and Gauntlets] [@Options3]

Table: Options1
with [|{$secondary}|{$details}] Cap
with [|{$secondary}|{$details}] Open Faced Helm 
with [|{$secondary}|{$details}] Cap and Shoulder Padding 
with [|{$secondary}|{$details}] Cap and {$details} Double Breasted Tunic 
with [|{$secondary}|{$details}] Open Faced Helm and [|{$secondary}|{$details}] Double Breasted Tunic
with [|{$secondary}|{$details}] Cap and [|{$secondary}|{$details}] Shoulder Padding
with [|{$secondary}|{$details}] Open Faced Helm and [|{$secondary}|{$details}] Shoulder Padding
with [|{$secondary}|{$details}] Cap and [|{$secondary}|{$details}] Shoulder Padding

Table: Options2
with [|{$secondary}|{$main}|{$details}] Open Faced Helm and [|{$secondary}|{$details}] Double Breasted Tunic
with [|{$secondary}|{$main}|{$details}] Sealed Helm and [|{$secondary}|{$details}] Shoulder Padding
with [|{$secondary}|{$main}|{$details}] Open Faced Helm and [|{$secondary}|{$details}] Shoulder Padding
with [|{$secondary}|{$main}|{$details}] Sealed Helm and [|{$secondary}|{$details}] Shoulder Padding

Table: Options3
with [|{$secondary}|{$main}|{$details}] Sealed Helm and [|{$secondary}|{$details}] Double Breasted Tunic
with [|{$secondary}|{$main}|{$details}] Sealed Helm and [|{$secondary}|{$details}] Shoulder Padding
with [|{$secondary}|{$main}|{$details}] Sealed Helm and {$details} Shoulder Padding

Table: Acces1
Boots and Gloves
Shoes
Boots and Gauntlets
Boots

Table: Details
{$details} Utility Belts with [|Gold|Silver|Brass|Titanium] details

Table: Weapon1
{$weapons} Pistol\n(DAMAGE:[|3|4|5]D[|+1|+2|] RATE: [|Single Shot|Single Shot and Burst])
{$weapons} Carbine [|(IR/UV Scope)|]\n(DAMAGE:[|4|5|6]D[|+1|+2|] RATE: [|Single Shot|Single Shot and Burst])

Table: Weapon2
{$weapons} Carbine [|(IR/UV Scope)|]\n(DAMAGE:[|4|5|6]D[|+1|+2|] RATE: [|Single Shot|Single Shot and Burst])
{$weapons} Rifle [|(IR/UV Scope)|]\n(DAMAGE:[|5|6|7]D[|+1|+2|] RATE: [|Single Shot|Single Shot and Burst])

Table: Weapon3
{$weapons} Rifle [|(IR/UV Scope)|]\n(DAMAGE:[|5|6|7]D[|+1|+2|] RATE: [|Single Shot|Single Shot and Burst])
{$weapons} Cannon [|(IR/UV Scope)|]\n(DAMAGE:[|7|8|9|10]D[|+1|+2|] RATE: [|Single Shot|Single Shot and Burst])

Table: Weapon4
\z
\nBayonette
\nCombat knife
\nMachette
\nGladius (Short Blade)
\nTanto
\nKatana
\nStunner Baton
\nTazergun
\z

Table: WeapType
Sonic
HEAP
AP
Beam-Laser
Pulse-Laser
Lo-Energy
Hi-Energy
Rail/Gauss
Plasma
Fusion
Ion
Phaser
Disruptor
Maser
Photon

Table: Equipment1
HandComm Unit [@Equipment2]
Headset Comm [@Equipment2]
No Comm Unit [@Equipment2]
IR/UV Headset Comm [@Equipment2]
HandComm Unit [@Equipment2]

Table: Equipment2
[|2|3|4]-[|Chemical|HE|HEAT|Plasma|Fusion|Photon|Fragmentation] Grenades [@Smoke] 
\z

Table: Smoke
\z
\z
and [|2|3|4]-Smoke Canisters